Play Kingdom Hearts 1 and 2 with a Wii remote!!!
#1
Here's a script I made for Kingdom Hearts 1 and 2 so they can be controlled by the wiimote and nunchuk (or two wiimotes).
The controls are easy to set up and get used to + it's a load of fun swinging the wii remote as a keyblade!



KINGDOM HEARTS SCRIPT
Code:
//
//   ---------------------
//KINGDOM HEARTS I/II - PCSX2
//   ---------------------
//
//Game Control          | Nunchuk Mode                    |Dual Wiimote Mode
//----------------------|---------------------------------|---------------------
//Camera                = Minus + Nunchuk Analog Stick    |Minus + Wiimote2 Dpad
//Movement              = Nunchuk Analog Stick            |Wiimote2 Dpad
//Triangle(Action)      = A                               |Same
//Square                = Z                               |Wiimote2 B
//Circle(Jump)          = C                               |Wiimote2 A
//Cross(Attack)         = Swing Wiimote or Nunchuk        |Swing either Wiimote
//R1(Lockon)            = B                               |Same
//L1(Magic)             = Plus                            |Same
//    Circle command    = C                               |Wiimote2 A
//    Square command    = Z                               |Wiimote2 B
//    Triangle command  = A                               |Same
//    Cross command     = B                               |Same
//Up(Menu)              = Up                              |Same
//Down(Menu)            = Down                            |Same
//Left(Menu)            = Left                            |Same
//Right(Menu)           = Right                           |Same
//Start(Pause)          = Home                            |Same
//(G)Fire               = B                               |Same
//(FS)Up                = C                               |Wiimote2 A
//(FS)Down              = Z                               |Wiimote2 B
//(FS)(KH2)Circle       = Minus + B                       |Same
//(FS)(KH2)Square       = Minus + A                       |Same
//(FS)(KH1)Circle       = C                               |Wiimote2 A
//(FS)(KH1)Square       = Z                               |Wiimote2 B
//Nunchuk Mode          = Attach Nunchuk                  |Same
//Dual Wiimote Mode     = Detach Nunchuk                  |Same
//Gummi Ship Mode(Led 4)= One + Plus                      |Same
//Exit Gummi Ship Mode  = One + Minus                     |Same
//Fly/Swim Mode(Led 3)  = Two + Plus                      |Same
//Exit Fly/Swim Mode    = Two + Minus                     |Same
//Volume Up             = One + Two + Up                  |Same
//Volume Down           = One + Two + Down                |Same
//Full Screen           = One + Two + A                   |Same
//Toggle Framelimitter  = One + Two + B                   |Same
//Show Wiimote Battery  = Home + C + Z                    |Home + Wiimote2 A + Wiimote2 B
//Exit Emulation        = One + Two + Home                |Same
//------------------------------------------------------------------------------
//
//
//
//
//
if var.start!=1 then
var.start = 1
// -------------------------
// User modifiable variables
// -------------------------
var.KingdomHeartsVersion=2                      //1 = Kingdom Hearts, 2 = Kingdom Hearts II
var.ControlMode=1                               //1 = Nunchuk Mode, 0 = Dual Wiimote Mode
var.GummiShipMode=0                             //1 = Gummi Ship Mode, 0 = Normal Mode
var.FlyAndSwimMode=0                            //1 = Fly/Swim Mode, 0 = Normal Mode
var.RumbleOnAttack=0                            //1 = Vibrate when attack, 0 = Normal
var.RumbleForce=150ms                           //How long to vibrate for each attack
var.Wiimote1Sensitivity=3                       //Change for sensitivity
var.Wiimote2Sensitivity=3                       //Change for sensitivity
var.NunchukSensitivity=2                        //Change for sensitivity
// -------------------------
endif
if var.KingdomHeartsVersion = 2 then var.khver = 'II' else var.khver = ' '
if Wiimote1.HasNunchuk then var.ControlMode = 1 else var.ControlMode = 0
if (Wiimote1.Plus and Wiimote1.One and not Wiimote1.Two) then var.GummiShipMode = 1
if (Wiimote1.Minus and Wiimote1.One and not Wiimote1.Two) then var.GummiShipMode = 0
if (Wiimote1.Plus and Wiimote1.Two and not Wiimote1.One) then var.FlyAndSwimMode = 1
if (Wiimote1.Minus and Wiimote1.Two and not Wiimote1.One) then var.FlyAndSwimMode = 0
if Wiimote2.up = true then var.dp2u = 1 else var.dp2u = 0
if Wiimote2.down = true then var.dp2d = 1 else var.dp2d = 0
if Wiimote2.left = true then var.dp2l = 1 else var.dp2l = 0
if Wiimote2.right = true then var.dp2r = 1 else var.dp2r = 0
if Wiimote1.Minus = true then
if var.KingdomHeartsVersion = 2 then
if var.ControlMode = 1 then
PPjoy1.Analog0 = Wiimote1.Nunchuk.JoyX
PPjoy1.Analog1 = Wiimote1.Nunchuk.JoyY
else
PPjoy1.Analog0 = var.dp2r - var.dp2l
PPjoy1.Analog1 = var.dp2d - var.dp2u
endif
else
if var.ControlMode = 1 then
if Wiimote1.Nunchuk.JoyX > 0.7 then PPjoy2.digital10 = true else PPjoy2.digital10 = false
if Wiimote1.Nunchuk.JoyX < -0.7 then PPjoy2.digital9 = true else PPjoy2.digital9 = false
else
PPjoy2.digital9 = Wiimote2.left
PPjoy2.digital10 = Wiimote2.right
endif
endif
PPjoy2.Analog0 = 0
PPjoy2.Analog1 = 0
else
PPjoy2.digital10 = false
PPjoy2.digital9 = false
if var.ControlMode = 1 then
PPjoy2.Analog0 = Wiimote1.Nunchuk.JoyX*1.25
PPjoy2.Analog1 = Wiimote1.Nunchuk.JoyY*1.25
else
PPjoy2.Analog0 = var.dp2r - var.dp2l
PPjoy2.Analog1 = var.dp2d - var.dp2u
endif
PPjoy1.Analog0 = 0
PPjoy1.Analog1 = 0
endif
ppjoy2.digital2 = Wiimote1.A
ppjoy2.digital3 = Wiimote1.B
ppjoy2.digital4 = Wiimote1.Home
ppjoy2.digital5 = Wiimote1.Plus
ppjoy2.digital11 = Wiimote1.Up
ppjoy2.digital12 = Wiimote1.Down
ppjoy2.digital13 = Wiimote1.Left
ppjoy2.digital14 = Wiimote1.Right
if var.ControlMode = 1 then
ppjoy2.digital6 = Wiimote1.Nunchuk.ZButton
else
ppjoy2.digital6 = Wiimote2.A
endif
if Wiimote.Plus = true then
ppjoy2.digital8 = Wiimote1.B
ppjoy2.digital3 = null
if var.ControlMode = 1 then
ppjoy2.digital7 = Wiimote1.Nunchuk.CButton
else
ppjoy2.digital7 = Wiimote2.B
endif
else
ppjoy2.digital3 = Wiimote1.B
if var.GummiShipMode=0 then
if var.ControlMode = 1 then
ppjoy2.digital7 = Wiimote1.Nunchuk.CButton
if var.KingdomHeartsVersion=1 then
ppjoy2.digital8 = Wiimote1.A or ((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote1.Nunchuk.gy > var.NunchukSensitivity or Wiimote1.Nunchuk.gy < -var.NunchukSensitivity) or (Wiimote1.Nunchuk.gx > var.NunchukSensitivity or Wiimote1.Nunchuk.gx < -var.NunchukSensitivity))
endif
if var.KingdomHeartsVersion=2 then
ppjoy2.digital8 = ((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote1.Nunchuk.gy > var.NunchukSensitivity or Wiimote1.Nunchuk.gy < -var.NunchukSensitivity) or (Wiimote1.Nunchuk.gx > var.NunchukSensitivity or Wiimote1.Nunchuk.gx < -var.NunchukSensitivity))
endif
else
ppjoy2.digital7 = Wiimote2.B
if var.KingdomHeartsVersion=1 then
ppjoy2.digital8 = Wiimote1.A or ((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote2.gx > var.Wiimote2Sensitivity or Wiimote2.gx < -var.Wiimote2Sensitivity) or (Wiimote2.gy > var.Wiimote2Sensitivity or Wiimote2.gy < -var.Wiimote2Sensitivity))
endif
if var.KingdomHeartsVersion=2 then
ppjoy2.digital8 = ((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote2.gx > var.Wiimote2Sensitivity or Wiimote2.gx < -var.Wiimote2Sensitivity) or (Wiimote2.gy > var.Wiimote2Sensitivity or Wiimote2.gy < -var.Wiimote2Sensitivity))
endif
endif
else
ppjoy2.digital3 = null
if var.ControlMode = 1 then
ppjoy2.digital7 = Wiimote1.Nunchuk.CButton
ppjoy2.digital8 = Wiimote1.B
else
ppjoy2.digital7 = Wiimote2.B
ppjoy2.digital8 = Wiimote1.B
endif
endif
endif
if var.FlyAndSwimMode = 1 then
if var.KingdomHeartsVersion = 2 then
if var.ControlMode = 1 then
if Wiimote1.Nunchuk.CButton = true then var.1a1a = 1 else var.1a1a = 0
if Wiimote1.Nunchuk.ZButton = true then var.1a1b = 1 else var.1a1b = 0
var.1a1 = var.1a1b-var.1a1a
PPjoy1.Analog1 = var.1a1
ppjoy2.digital7 = Wiimote1.B and Wiimote1.Minus
ppjoy2.digital6 = Wiimote1.A and Wiimote1.Minus
ppjoy2.digital3 = Wiimote1.B and not Wiimote1.Minus
ppjoy2.digital8 = (((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote1.Nunchuk.gy > var.NunchukSensitivity or Wiimote1.Nunchuk.gy < -var.NunchukSensitivity) or (Wiimote1.Nunchuk.gx > var.NunchukSensitivity or Wiimote1.Nunchuk.gx < -var.NunchukSensitivity))) and not Wiimote1.A
else
if Wiimote2.A = true then var.1a1a = 1 else var.1a1a = 0
if Wiimote2.B = true then var.1a1b = 1 else var.1a1b = 0
var.1a1 = var.1a1b-var.1a1a
PPjoy1.Analog1 = var.1a1
ppjoy2.digital7 = Wiimote1.B and Wiimote1.Minus
ppjoy2.digital6 = Wiimote1.A and Wiimote1.Minus
ppjoy2.digital3 = Wiimote1.B and not Wiimote1.Minus
ppjoy2.digital8 = (((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) or ((Wiimote2.gx > var.Wiimote2Sensitivity or Wiimote2.gx < -var.Wiimote2Sensitivity) or (Wiimote2.gy > var.Wiimote2Sensitivity or Wiimote2.gy < -var.Wiimote2Sensitivity))) and not Wiimote1.A
endif
else
if var.ControlMode = 1 then
ppjoy2.digital7 = Wiimote1.Nunchuk.CButton
ppjoy2.digital6 = Wiimote1.Nunchuk.ZButton
ppjoy2.digital3 = Wiimote1.B and not Wiimote1.Plus
else
ppjoy2.digital7 = Wiimote2.A
ppjoy2.digital6 = Wiimote2.B
ppjoy2.digital3 = Wiimote1.B and not Wiimote1.Plus
endif
endif
else
endif
if var.RumbleOnAttack = 1 and ((Wiimote1.gx > var.Wiimote1Sensitivity or Wiimote1.gx < -var.Wiimote1Sensitivity) or (Wiimote1.gy > var.Wiimote1Sensitivity or Wiimote1.gy < -var.Wiimote1Sensitivity)) then
Wiimote1.rumble=true
wait var.RumbleForce
Wiimote1.rumble=false
endif
if var.RumbleOnAttack = 1 and var.ControlMode=0 and ((Wiimote2.gx > var.Wiimote2Sensitivity or Wiimote2.gx < -var.Wiimote2Sensitivity) or (Wiimote2.gy > var.Wiimote2Sensitivity or Wiimote2.gy < -var.Wiimote2Sensitivity)) then
Wiimote2.rumble=true
wait var.RumbleForce
Wiimote2.rumble=false
endif
if (Wiimote1.One + Wiimote1.Two + Wiimote1.Home)=true then
key.esc=true
Wiimote.rumble=true
wait 0.5s
wiimote.rumble=false
key.esc=false
endif
if (Wiimote1.One + Wiimote1.Two + Wiimote1.B)=true then
key.f4=true
wait 100ms
key.f4=false
wait 200ms
endif
if (Wiimote1.One + Wiimote1.Two + Wiimote1.A)=true then
key.alt+key.enter=true
wait 100ms
key.alt+key.enter=false
wait 200ms
endif
if (Wiimote1.One + Wiimote1.Two + Wiimote1.Up)=true then
key.VolumeUp=true
key.VolumeUp=false
wait 100ms
endif
if (Wiimote1.One + Wiimote1.Two + Wiimote1.Down)=true then
key.VolumeDown=true
key.VolumeDown=false
wait 100ms
endif
if var.GummiShipMode=1 then var.GummiShipDebug='(G)'
if var.GummiShipMode=0 then var.GummiShipDebug=' '
if var.FlyAndSwimMode=1 then var.FASDebug='(FS)'
if var.FlyAndSwimMode=0 then var.FASDebug=' '
if Wiimote1.battery>19.2 then
if var.ControlMode = 1 then
if Wiimote1.HasNunchuk = true then
debug =  'KINGDOM HEARTS '+var.khver+'   -- 1 Wiimote and Nunchuk' +var.GummiShipDebug +var.FASDebug
Wiimote1.Leds=1
endif
else
if Wiimote.count<2  then
debug =  'KINGDOM HEARTS '+var.khver+'   -- Connect Nunchuk or 2nd Wiimote'
Wiimote1.Leds=15
wait 0.5s
Wiimote1.Leds=0
wait 0.5s
else
debug =  'KINGDOM HEARTS '+var.khver+'   -- 2 Wiimotes' +var.GummiShipDebug +var.FASDebug
Wiimote1.Leds=1
endif
endif
else
debug =  'KINGDOM HEARTS '+var.khver+'   -- ATTN:Wiimote1 battery at '+Wiimote.battery/1.92+'%!'
if var.lowbatrumbled=0 then
Wiimote.rumble=true
wait var.RumbleForce
wiimote.rumble=false
var.lowbatrumbled=1
wait 360s
var.lowbatrumbled=0
endif
endif
if Wiimote.count < 1  then
debug =  'KINGDOM HEARTS '+var.khver+'   -- Connect Wiimote via Bluetooth'
endif
if var.ControlMode = 0 then Wiimote2.Leds = 2 else Wiimote2.Leds = 0
if var.FlyAndSwimMode=1 then
Wiimote1.Leds = 5
endif
if var.GummiShipMode=1 then
Wiimote1.Leds = 9
if var.FlyAndSwimMode=1 then
Wiimote1.Leds = 13
endif
endif
if (var.ControlMode=1 and (Wiimote1.Home + Wiimote1.Nunchuk.CButton + Wiimote1.Nunchuk.ZButton)=true) or (var.ControlMode=0 and (Wiimote1.Home + Wiimote2.A + Wiimote2.B)=true) then
if var.ControlMode=0 then debug='KINGDOM HEARTS '+var.khver+'   -- 1: '+Wiimote1.battery/1.92+'%; 2: '+Wiimote2.battery/1.92+'%'
if var.ControlMode=1 then debug='KINGDOM HEARTS '+var.khver+'   -- Wiimote1: '+Wiimote1.battery/1.92+'%;'
If Wiimote1.Battery > 0 and Wiimote1.Battery <= 48 Then Wiimote1.Leds = 1
If Wiimote1.Battery > 48 and Wiimote1.Battery <= 96 Then Wiimote1.Leds = 3
If Wiimote1.Battery > 96 and Wiimote1.Battery <= 144 Then Wiimote1.Leds = 7
If Wiimote1.Battery > 144 and Wiimote1.Battery <= 192 Then Wiimote1.Leds = 15
If Wiimote2.Battery > 0 and Wiimote2.Battery <= 48 Then Wiimote2.Leds = 1
If Wiimote2.Battery > 48 and Wiimote2.Battery <= 96 Then Wiimote2.Leds = 3
If Wiimote2.Battery > 96 and Wiimote2.Battery <= 144 Then Wiimote2.Leds = 7
If Wiimote2.Battery > 144 and Wiimote2.Battery <= 192 Then Wiimote2.Leds = 15
endif

KINGDOM HEARTS LILYPAD CONFIGURATOR
Code:
//KH/KH2 Wiimote Setup Script
//
//Simply connect your wii remote via bluetooth,
//Run this script,
//Follow the instructions
//Eg. If it says Press Triangle then Press A,
// You go to LilyPad, press the triangle button
// and press the A button on your wii remote.
// It will then map the correct control to the Triangle key
//Once configuration is complete,
//Check your configuration against the attached image
//If it is the same, you're good to go,
//Just open the kingdom hearts script and run it.
//
//

Wiimote1.leds=1
if var.start!=1 then
var.start=1
var.step=0
endif
if var.step=0 then
debug = var.step+': Press Right Analog Stick Right then Press A'
if Wiimote.A = true then
PPjoy1.Analog0=1
wait 1s
PPjoy1.Analog0=0
var.step++
endif
endif
if var.step=1 then
debug = var.step+': Press Right Analog Stick Left then Press A'
if Wiimote.A = true then
PPjoy1.Analog0=-1
wait 1s
PPjoy1.Analog0=0
var.step++
endif
endif
if var.step=2 then
debug = var.step+': Press Right Analog Stick Down then Press A'
if Wiimote.A = true then
PPjoy1.Analog1=1
wait 1s
PPjoy1.Analog1=0
var.step++
endif
endif
if var.step=3 then
debug = var.step+': Press Right Analog Stick Up then Press A'
if Wiimote.A = true then
PPjoy1.Analog1=-1
wait 1s
PPjoy1.Analog1=0
var.step++
endif
endif
if var.step=4 then
debug = var.step+': Press Left Analog Stick Right then Press A'
if Wiimote.A = true then
PPjoy2.Analog0=1
wait 1s
PPjoy2.Analog0=0
var.step++
endif
endif
if var.step=5 then
debug = var.step+': Press Left Analog Stick Left then Press A'
if Wiimote.A = true then
PPjoy2.Analog0=-1
wait 1s
PPjoy2.Analog0=0
var.step++
endif
endif
if var.step=6 then
debug = var.step+': Press Left Analog Stick Down then Press A'
if Wiimote.A = true then
PPjoy2.Analog1=1
wait 1s
PPjoy2.Analog1=0
var.step++
endif
endif
if var.step=7 then
debug = var.step+': Press Left Analog Stick Up then Press A'
if Wiimote.A = true then
PPjoy2.Analog1=-1
wait 1s
PPjoy2.Analog1=0
var.step++
endif
endif
if var.step=8 then
debug = var.step+': Press Left Analog Stick Up then Press A'
if Wiimote.A = true then
PPjoy2.Analog1=-1
wait 1s
PPjoy2.Analog1=0
var.step++
endif
endif
if var.step=9 then
debug = var.step+': Press Dpad Up then Press A'
if Wiimote.A = true then
PPjoy2.Digital11=1
wait 1s
PPjoy2.Digital11=0
var.step++
endif
endif
if var.step=10 then
debug = var.step+': Press Dpad Right then Press A'
if Wiimote.A = true then
PPjoy2.Digital14=1
wait 1s
PPjoy2.Digital14=0
var.step++
endif
endif
if var.step=11 then
debug = var.step+': Press Dpad Down then Press A'
if Wiimote.A = true then
PPjoy2.Digital12=1
wait 1s
PPjoy2.Digital12=0
var.step++
endif
endif
if var.step=12 then
debug = var.step+': Press Dpad Left then Press A'
if Wiimote.A = true then
PPjoy2.Digital13=1
wait 1s
PPjoy2.Digital13=0
var.step++
endif
endif
if var.step=13 then
debug = var.step+': Press Triangle then Press A'
if Wiimote.A = true then
PPjoy2.Digital2=1
wait 1s
PPjoy2.Digital2=0
var.step++
endif
endif
if var.step=14 then
debug = var.step+': Press R1 then Press A'
if Wiimote.A = true then
PPjoy2.Digital3=1
wait 1s
PPjoy2.Digital3=0
var.step++
endif
endif
if var.step=15 then
debug = var.step+': Press Start then Press A'
if Wiimote.A = true then
PPjoy2.Digital4=1
wait 1s
PPjoy2.Digital4=0
var.step++
endif
endif
if var.step=16 then
debug = var.step+': Press L1 then Press A'
if Wiimote.A = true then
PPjoy2.Digital5=1
wait 1s
PPjoy2.Digital5=0
var.step++
endif
endif
if var.step=17 then
debug = var.step+': Press Square then Press A'
if Wiimote.A = true then
PPjoy2.Digital6=1
wait 1s
PPjoy2.Digital6=0
var.step++
endif
endif
if var.step=18 then
debug = var.step+': Press Circle then Press A'
if Wiimote.A = true then
PPjoy2.Digital7=1
wait 1s
PPjoy2.Digital7=0
var.step++
endif
endif
if var.step=19 then
debug = var.step+': Press Cross then Press A'
if Wiimote.A = true then
PPjoy2.Digital8=1
wait 1s
PPjoy2.Digital8=0
var.step++
endif
endif
if var.step=20 then
debug = var.step+': Press L2 then Press A'
if Wiimote.A = true then
PPjoy2.Digital9=1
wait 1s
PPjoy2.Digital9=0
var.step++
endif
endif
if var.step=21 then
debug = var.step+': Press R2 then Press A'
if Wiimote.A = true then
PPjoy2.Digital10=1
wait 1s
PPjoy2.Digital10=0
var.step++
endif
endif
if var.step=22 then
debug = var.step+': Your lilypad config is set up!'
endif




What you need:
-The above scripts,
-A wii remote and a nunchuk (or two wiimotes),
-A bluetooth enabled computer,
-These files

.zip   Glovepie 0.30.zip (Size: 2,1 MB / Downloads: 1.113)

.zip   PPJoySetup.zip (Size: 1,77 MB / Downloads: 1.251)
-Common sense Smile



What your LilyPad configuration should look like (Check at end of configurator):
   


Instructions :
Connect your Wiimote to your PC via bluetooth (Tutorial)
Install PPjoy
Start Glovepie 0.30
Click CP-Settings>PPjoy
Click 'Add..' and create two PPjoy joysticks
The first just needs two axes (Analog 0 and 1)
The second needs;
Two axes (Analog 0 and 1),
1 POV hat,
11 Buttons.

Map the POV hat as;
North - digital11
South - digital12
West - digital13
East - digital14

Map the buttons as default;
Button1 - digital0
Button2 - digital1
Etc...

Enter PCSX2, go to Config>Configure, and select LilyPad for both controllers
Press OK, then go to Config>Controllers
Click the Pad1 tab.
Run the Kingdom Hearts Configurator script in glovepie
Follow the instructions and it will map all the correct controls for you
Click Apply in Lilypad
Run the Kingdom Hearts script in Glovepie.
Start Kingdom Hearts I or II and feel the power of the Keyblade in your hands!






Any comments appreciated,
-Marcus
AMD Athlon 64 X2 Dual Core 3600+ @2.33GHz
NVIDIA Geforce 9500GT 512MB @C:600MHz M:475MHz
2GB DDR2-333 @778MHz
Vista Ultimate x86

Reply

Sponsored links

#2
wow this is cool, i would like to try it (but don't have a wiimote Sad, i would REALLY like to swing the keyblade like if i were Sora Tongue)
Windows 7 64bit
Intel Pentium Dual-Core E5200 OC to 3.6GHz, Intel GMA x4500, 1GB DDR2

NinjaMight just work on next guideNinja
Reply
#3
you need bluetooth for that too luis
Reply
#4
i know Tongue
Windows 7 64bit
Intel Pentium Dual-Core E5200 OC to 3.6GHz, Intel GMA x4500, 1GB DDR2

NinjaMight just work on next guideNinja
Reply
#5
Haha, nice. Anything else fun with the wiimote or is it just swinging the key? (Which is pretty neat on it's own!)
www.twitch.tv/krazytrumpeter05
Want to stream your games? Let me know and I can help you get set up with Open Broadcaster Software.
Reply
#6
(03-31-2009, 01:33 AM)KrazyTrumpeter05 Wrote: Haha, nice. Anything else fun with the wiimote or is it just swinging the key? (Which is pretty neat on it's own!)

Just updated it so you can jump by swinging the nunchuck upward Smile

I'm also thinking of making it so you hold the corresponding button and swing the wiimote to use magic, not sure if this would be easy to do while fighting armies of heartless though Smile


Has anybody else tried this yet?
AMD Athlon 64 X2 Dual Core 3600+ @2.33GHz
NVIDIA Geforce 9500GT 512MB @C:600MHz M:475MHz
2GB DDR2-333 @778MHz
Vista Ultimate x86

Reply
#7
I intend to try it myself
I asked my cousin to help me find his Bluetooth USB so I can try it out
if I manage to get my hands on it, I'll try it out and tell you some suggestions
Reply
#8
there's one thing i suggest change the "[quote]" bbcode to "[code]" (it's much easier to copy that way Smile)

EDIT: and does the jump work the same way as with a real controller (the longer you hold the higher it jumps) Unsure
Windows 7 64bit
Intel Pentium Dual-Core E5200 OC to 3.6GHz, Intel GMA x4500, 1GB DDR2

NinjaMight just work on next guideNinja
Reply
#9
[quote='LuisR14' pid='35991' dateline='1238546252']
there's one thing i suggest change the "[quote]" bbcode to "[code]" (it's much easier to copy that way Smile)

EDIT: and does the jump work the same way as with a real controller (the longer you hold the higher it jumps) Unsure
[/quote]

Done that, thanks Luis

And no that wouldn't be possible because in kingdom hearts it just accepts the button press and jumps a default amount. All I've done is mapped the movement of the nunchuck to the pressing of the jump key.
..Although that would be pretty neat.


+Thanks Chivi, looking forward to a second opinion Smile
AMD Athlon 64 X2 Dual Core 3600+ @2.33GHz
NVIDIA Geforce 9500GT 512MB @C:600MHz M:475MHz
2GB DDR2-333 @778MHz
Vista Ultimate x86

Reply
#10
(04-01-2009, 06:41 PM)marcus Wrote:
(04-01-2009, 02:37 AM)LuisR14 Wrote: EDIT: and does the jump work the same way as with a real controller (the longer you hold the higher it jumps) Unsure
And no that wouldn't be possible because in kingdom hearts it just accepts the button press and jumps a default amount. All I've done is mapped the movement of the nunchuck to the pressing of the jump key.
..Although that would be pretty neat.
well what i meant is for Kingdom Hearts 2 (in that game the High Jump ability says the longer you hold the jump button the higher you jump (as seen in the image) Smile)
   
Windows 7 64bit
Intel Pentium Dual-Core E5200 OC to 3.6GHz, Intel GMA x4500, 1GB DDR2

NinjaMight just work on next guideNinja
Reply




Users browsing this thread: 1 Guest(s)